🚀 Top 3 team members with the most active tasks

Type

Relations

🚀 Top 3 team members with the most active tasks

Option 1)

"_______________________________" + "\n" + 
"Members with the most active tasks:" + "\n" +
lets(
    activeTasks, 
    filter(
        prop("Tasks Relation"), 
        or(
            current.prop("Status") == "Not started", 
            current.prop("Status") == "In progress"
        )
    ),
    allAssignees, 
    activeTasks.map(current.prop("Assignee")).flat(),
    uniqueAssignees, 
    allAssignees.unique(),
    join(
        uniqueAssignees.map(
            let(
                c, current,
                "→ " + format(allAssignees.filter(current == c).length()).style("pink,b,u") + " → " + c
            )
        ).sort().reverse().slice(0, 3),
        "\n"
    )
)

This formula also counts "collaborative tasks," where multiple members are assigned.

Option 2)

"_______________________________" + "\n" + 
"Members with the most active tasks:" + "\n" + 
lets(
    activeTasks, 
    filter(
        prop("Tasks Relation"), 
        or(
            current.prop("Status") == "Not started", 
            current.prop("Status") == "In progress"
        )
    ),
    taskAssignee, 
    activeTasks.map(current.prop("Assignee")),
    join(
        taskAssignee.unique().map(
            let(
                c, current,
                "→ " + format(taskAssignee.filter(current == c).length()).style("pink,b,u") + " → " + c
            )
        ).sort().reverse().slice(0, 3),
        "\n"
    )
)

This formula only counts "individual tasks" (where only one member is assigned). Collaborative tasks are omitted from the calculation.

Output example (the middle section shows the formula results):

Instructions to make such a summary card:

Create a new database called “Stats”.
Add one entry and name it “Team Stats”.
Create relation property and connect it to your tasks database (make sure it’s two way relation).
Go to your “Tasks” database.

Open page template and in the “Stats” relation, connect “Team Stats” entry.
Go back to your tasks and make sure you’re in the unfiltered view with all the tasks.
Select all tasks → Edit Property → “Stats”
Select “Team Stats” entry.

Go back to your “Stats” database.
Add formula property and call it “Most active”.
Paste one of the above formulas to this formula property.

Change the “Tasks Relation” to your actual task relation property.
Replace “Status”.
If your task status properties have different names than “Not started” or “In progress”, change them accordingly.
Save.

Go back to your “Stats” database and change the view to Gallery.

Change card preview to “None”.
Go to properties settings and show (eye icon) the formula property we just added.

This advanced formula may be challenging to implement if you have different database settings, want to adapt it for personal use rather than team use, or have different status property options.

If you need help, hire us to have it done in no time or with more stats calculated!

I want it quick!